Sie haben eine große, schöne PowerPoint-Präsentation und wollen die Notizen daraus abschreiben? Aber nicht doch – benützen Sie doch folgenden VBA-Code:

Sub Export_Notes()
Dim myPres As Presentation
Dim myPath As Variant
Dim mySlide As Slide
Dim I As Long
Dim myDoc As New Word.Document
Dim WordApp As New Word.Application
On Error GoTo Fehler
     
    Set WordApp = CreateObject("Word.Application")
    WordApp.Visible = True
    Set myDoc = WordApp.Documents.Add
    myDoc.Activate
    Set myPres = PowerPoint.ActivePresentation
    myPath = Left(myPres.FullName, Len(myPres.FullName) - 5) & "_notes.docx"
    For Each mySlide In myPres.Slides
        WordApp.Selection.TypeText "Folie " & mySlide.SlideNumber & vbCrLf
        For I = 1 To mySlide.NotesPage.Shapes.Count
            If mySlide.NotesPage.Shapes(I).TextFrame.HasText Then
                WordApp.Selection.TypeText mySlide.NotesPage.Shapes(I).TextFrame.TextRange & vbCrLf
            End If
        Next I
    Next mySlide
Schluss:
    myDoc.SaveAs2 FileName:=myPath, FileFormat:= _
        wdFormatXMLDocument, LockComments:=False, Password:="", AddToRecentFiles _
        :=True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts _
        :=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False, CompatibilityMode:=15
    
    Set myPres = Nothing
    MsgBox "Export der Notizen erfolgte in" & vbCrLf & myPath, vbOKOnly, "Fertig"
    Exit Sub
Fehler:
    MsgBox "Error " & Err.Number & " – " & Err.Description
    GoTo Schluss
End Sub